HouseBot

Code: Select all

@echo off
cls
:Start
echo HouseBot started on %Date% at %Time%
start "HouseBot Server" /MIN /ABOVENORMAL /WAIT C:\Progra~1\HouseBot\HouseBotServer.exe
echo HouseBot Server Terminated on %Date% at %Time%
goto Start

Code: Select all

@ECHO OFF
SET COUNT=0
SET MAX=3
:Loop
Echo Housebot Automation Server Started on %Date% at %Time% 
start "HouseBot Server" /MIN /ABOVENORMAL /WAIT C:\Progra~1\Housebot\HouseBotServer.exe 
Echo Housebot Automation Server Terminated on %Date% at %Time% 
REM **** Put something here to alert you that HB has restarted.****
SET /A COUNT=COUNT+1
If "%COUNT%"=="%MAX%" goto Exit
goto Loop
:Exit
REM ****Put something here to alert you that HB has looped it's max number of times and is dead.****

Code: Select all

Option Explicit
Dim objWSHShell, HbLoopMax, HbAppStart, HbLoopCount, EmailFrom, EmailNotify, objEmail, HbAppPath
Dim EmailServer, RestartWarnSub, RestartWarnMsg, MaxLoopWarnSub, MaxLoopWarnMsg, RsltEvtAdd

'************************************************************************
' Set Parameters for Maximum Loops, HB Location and Email
HbLoopMax      = 3
HbAppPath      = "C:\Progra~1\HouseBot\HouseBotServer.exe"
EmailFrom      = "HouseBot"  ' ***This may need to be a valid email address from your ISP***
EmailNotify    = "[email protected]"
EmailServer    = "smtp.YourMailServer.com"
RestartWarnSub = "Notice: HouseBot Error"
RestartWarnMsg = "HouseBot has restarted, you may want to check it."
MaxLoopWarnSub = "Warning: Critical HouseBot Error"
MaxLoopWarnMsg = "HouseBot has restarted " & HbLoopMax & " times and is now dead. Manual intervention required."
'************************************************************************

'Heres a list of event codes to use when calling the AddAppEvent function
'0   SUCCESS
'1   ERROR
'2   WARNING
'4   INFORMATION
'8   AUDIT_SUCCESS
'16  AUDIT_FAILURE

'Begin Code to loop through restarts
HbLoopCount=0
do until HbLoopCount = HbLoopMax
    HbLoopCount=HbLoopCount+1
    Set objWSHShell = WScript.CreateObject("WScript.Shell")
    objWSHShell.Run HbAppPath, 1, true
    AddAppEvent 1, RestartWarnMsg
    SendEmail RestartWarnSub, RestartWarnMsg
    Set objWSHShell = Nothing
loop
AddAppEvent 2, MaxLoopWarnMsg
SendEmail MaxLoopWarnSub, MaxLoopWarnMsg

'Function to Send Email
Public Function SendEmail(EmailSubject, EmailMessage)
    Set objEmail = CreateObject("CDO.Message")
    objEmail.From = EmailFrom
    objEmail.To = EmailNotify
    objEmail.Subject = EmailSubject
    objEmail.Textbody = EmailMessage
    objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
    objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = EmailServer
    objEmail.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 25
    objEmail.Configuration.Fields.Update
    objEmail.Send
    Set objEmail = Nothing
End Function

'Function to add restarts to Local Application Event log
Public Function AddAppEvent(EventLevel, EventMessage)
    set objWSHShell = Wscript.CreateObject("Wscript.Shell")
    RsltEvtAdd = objWSHShell.LogEvent(EventLevel, EventMessage)
    set objWSHShell = nothing
End Function